// - loise v.01 - 19 sept 2003
// elout <http://www.xs4all.nl/~elout/>
// based on my early zab0/loise work created around 1999

float zpos;

//------mouse rotation stuff
int mx,my,sx=140,sy=120, middenx,middeny;
float xangle,yangle,zangle;


int points=300;

float xd[]=new float[points];
float yd[]=new float[points];
float zd[]=new float[points];
float qdx,qdy,qdz;

int nolights=4;

int fx=0;
int maxfx=5;
int mygrey=80;

void setup()
{
  size(500,500);
  background(mygrey,mygrey,mygrey);
  zpos=0.0f;

  middenx=width/2;
  middeny=height/2;

  //noStroke();
  stroke(0,0,0);
  
  fill(255,255,255,160);
  lights();
  //set-up the lights
  for (int i=0;i<nolights;i++)
  {
    g.lightR[i] = 1.0f;
    g.lightG[i] = 1.0f;
    g.lightB[i] = 1.0f;
    g.lightX[i]= 0.0f;
    g.lightY[i]= 0.0f;
    g.lightZ[i]= 0.0f;
    g.lightKind[i] = DIFFUSE;
  }  
  
}

void loop()
{
  //translate the model to the middle of the screen
  translate(width/2, height/2, zpos);

  //rotate using mouseposition
  mx=mouseX;
  my=mouseY;
  if ( mx > middenx){sx=0-((middenx-mx));}
  else{sx=((mx-middenx));}
  if ( my > middeny){sy=0-((middeny-my));}
  else{sy=((my-middeny));}
  xangle= (sy/1800.0f);
  yangle= ((sx-sy)/1800.0f);
  zangle= (sx/1800.0f);

  if(keyPressed)
  {
    if (key == UP)
    {
      zpos=zpos+20.0f;
    }
    if (key == DOWN)
    {
      zpos=zpos-20.0f;
    }
    if (key == 'a' || key == 'A')
    {
       noStroke();
    }
    if (key == 's' || key == 'S')
    {
      stroke(0,0,0);
    }
    
  }

  //calculate the 3D model
  for (int i=points-1; i>0; i--)
  {
    xd[i]=xd[i-1];
    yd[i]=yd[i-1];
    zd[i]=zd[i-1];
  }
  //first point gets updated
  xd[0]=(mx-middenx)/1.2;
  yd[0]=(my-middeny)/1.2;
  zd[0]=sx/1.2;
  
  //set the light position
  for (int i=0,ii=0;i<nolights;i++)
  {
    ii=i*(points/nolights);
    g.lightX[i]=xd[ii];
    g.lightY[i]=yd[ii];
    g.lightZ[i]=zd[ii];
  }

  for (int i=0;i<points;i++)
  {
	qdy=yd[i];
	qdz=zd[i];
	yd[i]=(float)( qdy*cos(xangle) - qdz*sin(xangle));
	zd[i]=(float)( qdz*cos(xangle) + qdy*sin(xangle));
	qdz=zd[i];
	qdx=xd[i];
	zd[i]=(float)( qdz*cos(yangle) - qdx*sin(yangle));
	xd[i]=(float)( qdx*cos(yangle) + qdz*sin(yangle));
	qdx=xd[i];
	qdy=yd[i];
	xd[i]=(float)( qdx*cos(zangle) - qdy*sin(zangle));
	yd[i]=(float)( qdy*cos(zangle) + qdx*sin(zangle));
  }
    
  //draw the 3D model
  if (fx==0){beginShape(TRIANGLE_STRIP);}
  if (fx==1){beginShape(TRIANGLES);}
  if (fx==2){beginShape(QUAD_STRIP);}
  if (fx==3){beginShape(QUADS);}
  if (fx==4){beginShape(TRIANGLE_STRIP);}
  if (fx==5){ } //do nothing - causes the smear effect - different from noBackground()
  
   //LINES, LINE_STRIP, LINE_LOOP, TRIANGLES, TRIANGLE_STRIP, QUADS, QUAD_STRIP, and POLYGON
  for (int i=0;i<points;i++)
  {
   vertex(xd[i], yd[i],zd[i]);   
  }
  endShape();
  
  //just add a little delay so the system can handle other stuff as well
  delay(15);
}

void mousePressed() 
{
  //change the light color
  for (int j=0;j<nolights;j++)
  {  
    g.lightR[j] = (random(80)/100.0f)+0.2f;
    g.lightG[j] = (random(80)/100.0f)+0.2f;
    g.lightB[j] = (random(80)/100.0f)+0.2f;
  }

  //fx increaser
  fx++;
  if (fx>maxfx){fx=0;}
    
  //change the background color
  mygrey=(int) random(255);
  background(mygrey,mygrey,mygrey);
}